exitbufr.f

Go to the documentation of this file.

C> @file
C> @brief Reset the NCEPLIBS-bufr software for potential dynamic
C> reallocation of memory.
C>
C> @author J. Ator @date 2015-03-02
 
C> This subroutine frees all dynamically-allocated memory,
C> closes all logical units that are open within the
C> NCEPLIBS-bufr software, and resets the library to all of its
C> default settings as though it had never been called.
C>
C> @remarks
C> - Calling this subroutine allows an application program to
C>   potentially resize arrays and reallocate memory all over again
C>   with a new subsequent series of calls to subroutines isetprm()
C>   and openbf().  However, if and when this subroutine is called,
C>   there is no longer any internal memory available within the
C>   NCEPLIBS-bufr software, and the remainder of the library becomes
C>   essentially unusable within the application program, unless
C>   and until subroutine openbf() is called once again to
C>   dynamically allocate new array space.  This may be a useful
C>   capability for application programs that are finished with
C>   using the NCEPLIBS-bufr software and wish to move on to other
C>   unrelated tasks without continuing to tie up all of the
C>   allocated memory space within the library.  Otherwise, and
C>   unless there's a need to change parameter sizes following the
C>   first call to subroutine openbf(), then there's no need to ever
C>   call this subroutine within an application program, since all
C>   allocated memory will automatically get freed anyway by the
C>   operating system once the application program terminates.
C>
C> @author J. Ator @date 2015-03-02
        RECURSIVE SUBROUTINE exitbufr
 
        use bufrlib
 
        USE modv_im8b
        USE modv_ifopbf
        USE modv_nfiles
 
        USE moda_stbfr
        USE moda_s01cm
 
        COMMON /tablef/ cdmf
 
        CHARACTER*1 cdmf
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
C       Check for I8 integers.
 
        IF (im8b) THEN
          im8b = .false.
 
          CALL exitbufr
 
          im8b = .true.
          RETURN
        END IF
 
C       Close any logical units that are open to the library.
 
        DO jj = 1, nfiles
          IF ( iolun(jj) .NE. 0 ) CALL closbf( abs(iolun(jj)) )
        END DO
 
C       Deallocate all allocated memory.
 
        CALL ardllocf
 
        IF ( cdmf .EQ. 'Y' ) CALL dlloctbf_c
 
C       Reset the library.
 
        ns01v = 0
        ifopbf = 0
 
        RETURN
        END