igetfxy.f

Go to the documentation of this file.

C> @file
C> @brief Search for a valid FXY number within a character string.
C>
C> @author Ator @date 2007-01-19
 
C> This function looks for and returns a valid FXY number
C> from within the given input string. The FXY number may be in
C> format of either FXXYYY or F-XX-YYY within the input string, but
C> it is always returned in format FXXYYY upon output.
C>
C> @param[in] STR - character*(*): input string.
C> @param[in] CFXY - character*6: FXY number in format FXXYYY.
C>
C> @return
C> - 0 normal return.
C> - -1 could not find a valid FXY number in STR.
C>
C> @author Ator @date 2007-01-19
        FUNCTION igetfxy ( STR, CFXY )
 
        CHARACTER*(*)   str
        CHARACTER*6     cfxy
 
        parameter( lstr2 = 120 )
        CHARACTER*(LSTR2)  str2
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
        igetfxy = -1
 
        lstr = len( str )
        IF ( lstr .LT. 6 ) RETURN
 
C       Left-justify a copy of the input string.
 
        IF ( lstr .GT. lstr2 ) THEN
            str2(1:lstr2) = str(1:lstr2)
        ELSE
            str2 = str
        ENDIF
        str2 = adjustl( str2 )
        IF ( str2 .EQ. ' ' ) RETURN
 
C       Look for an FXY number.
 
        IF ( index( str2, '-' ) .NE. 0 ) THEN
C           Format of field is F-XX-YYY.
            cfxy(1:1) = str2(1:1)
            cfxy(2:3) = str2(3:4)
            cfxy(4:6) = str2(6:8)
        ELSE
C           Format of field is FXXYYY.
            cfxy = str2(1:6)
        ENDIF
 
C       Check that the FXY number is valid.
 
        IF ( numbck( cfxy ) .EQ. 0 ) igetfxy = 0
 
        RETURN
        END