invcon.f

Go to the documentation of this file.

C> @file
C> @brief Search a specified window for a conditional node.
C>
C> @author Woollen @date 1994-01-06
 
C> This function searches a "window" (see below remarks) for an
C> element identified in the user string as a conditional node.
C> A conditional node is an element which must meet a condition in order to be
C> read from or written to a data subset.
C> If a conditional element is found and it conforms to the
C> condition, then the index of the element within the window is returned;
C> otherwise a value of zero is returned.
C>
C> @note: See getwin() for an explanation of "windows" within the context
C> of a bufr data subset.
C>
C> @param[in] NC - integer: condition code:
C> - 1 '=' (equal)
C> - 2 '!' (not equal)
C> - 3 '<' (less than)
C> - 4 '>' (greater than)
C> @param[in] LUN - integer: i/o stream index into internal memory arrays
C> @param[in] INV1 - integer: first index of window to search
C> @param[in] INV2 - integer: last index of window to search
C>
C> @return integer: index within window of conditional node
C> conforming to specified condition.
C> - 0 none found.
C>
C> @author Woollen @date 1994-01-06
      FUNCTION invcon(NC,LUN,INV1,INV2)
 
      USE moda_usrint
 
      COMMON /usrstr/ nnod,ncon,nods(20),nodc(10),ivls(10),kons(10)
      COMMON /quiet / iprt
 
C----------------------------------------------------------------------
C----------------------------------------------------------------------
 
C  CHECK THE INVENTORY INTERVAL
C  ----------------------------
 
      IF(inv1.LE.0 .OR. inv1.GT.nval(lun)) GOTO 99
      IF(inv2.LE.0 .OR. inv2.GT.nval(lun)) GOTO 99
 
C  FIND AN OCCURANCE OF NODE IN THE WINDOW MEETING THIS CONDITION
C  --------------------------------------------------------------
 
      DO invcon=inv1,inv2
      IF(inv(invcon,lun).EQ.nodc(nc)) THEN
         IF(kons(nc).EQ.1 .AND. val(invcon,lun).EQ.ivls(nc)) GOTO 100
         IF(kons(nc).EQ.2 .AND. val(invcon,lun).NE.ivls(nc)) GOTO 100
         IF(kons(nc).EQ.3 .AND. val(invcon,lun).LT.ivls(nc)) GOTO 100
         IF(kons(nc).EQ.4 .AND. val(invcon,lun).GT.ivls(nc)) GOTO 100
      ENDIF
      ENDDO
 
99    invcon = 0
      IF(iprt.GE.2) THEN
      CALL errwrt('++++++++++++++BUFR ARCHIVE LIBRARY+++++++++++++++++')
      CALL errwrt('BUFRLIB: INVCON - RETURNING WITH A VALUE OF 0')
      CALL errwrt('++++++++++++++BUFR ARCHIVE LIBRARY+++++++++++++++++')
      CALL errwrt(' ')
      ENDIF
 
C  EXIT
C  ----
 
100   RETURN
      END