iupm.f

Go to the documentation of this file.

C> @file
C> @brief Decode an integer value from a character string.
C>
C> @author J. Woollen @date 1994-01-06
 
C> Decode an integer value from a character string.
C>
C> This function decodes an integer value from within a
C> specified number of bits of a character string, starting
C> with the first bit of the first byte of the string.
C>
C> This function is the logical inverse of subroutine ipkm().
C>
C> @param[in] CBAY  - character*(*): String.
C> @param[in] NBITS - integer: Number of bits from CBAY to be decoded.
C> @returns iupm - integer: Decoded value.
C>
C> @author J. Woollen @date 1994-01-06
      RECURSIVE FUNCTION iupm(CBAY,NBITS) RESULT(IRET)
 
      USE modv_im8b
 
      COMMON /hrdwrd/ nbytw,nbitw,iord(8)
 
      CHARACTER*128 bort_str
      CHARACTER*8   cbay
      CHARACTER*8   cint
      dimension     int(2)
      equivalence(cint,int)
 
C----------------------------------------------------------------------
C----------------------------------------------------------------------
 
C     Check for I8 integers.
 
      IF(im8b) THEN
         im8b=.false.
 
         CALL x84(nbits,my_nbits,1)
         iret = iupm(cbay,my_nbits)
 
         im8b=.true.
         RETURN
      ENDIF
 
      iret = 0
      IF(nbits.GT.nbitw) GOTO 900
      cint = cbay
      int(1) = irev(int(1))
      iret = ishft(int(1),nbits-nbitw)
 
C  EXITS
C  -----
 
      RETURN
900   WRITE(bort_str,'("BUFRLIB: IUPM - NUMBER OF BITS BEING UNPACKED'//
     . ', NBITS (",I4,"), IS > THE INTEGER WORD LENGTH ON THIS '//
     . 'MACHINE, NBITW (",I3,")")') nbits,nbitw
      CALL bort(bort_str)
      END