lstjpb.f

Go to the documentation of this file.

C> @file
C> @brief Search backwards from a specified node of the jump/link table
C> for a node of a specified type.
C>
C> @author Woollen @date 1994-01-06
 
C> This function searches backwards, beginning from a given
C> node within the jump/link table, until it finds the most recent
C> node of type jbtyp. The internal jmpb array is used to jump
C> backwards within the jump/link table, and the function returns
C> the table index of the found node. If the input node itself is
C> of type jbtyp, then the function simply returns the index of that
C> same node.
C>
C> @note See tabsub() for an
C> explanation of the various node types present within an internal
C> jump/link table.
C>
C> @param[in] NODE - integer: jump/link table index of entry to begin
C> searching backwards from
C> @param[in] LUN - integer: I/O stream index into internal memory arrays
C> @param[in] JBTYP - character*(*): type of node for which to search
C>
C> @return - integer: index of first node of type jbtyp found by
C> jumping backwards from input node
C> - 0 no such node found
C>
C> @author Woollen @date 1994-01-06
      FUNCTION lstjpb(NODE,LUN,JBTYP)
 
      USE moda_msgcwd
      USE moda_tables
 
      CHARACTER*(*) jbtyp
      CHARACTER*128 bort_str
 
C----------------------------------------------------------------------
C----------------------------------------------------------------------
 
      IF(node.LT.inode(lun)) GOTO 900
      IF(node.GT.isc(inode(lun))) GOTO 901
 
      nod = node
 
C  FIND THIS OR THE PREVIOUS "JBTYP" NODE
C  --------------------------------------
 
10    IF(typ(nod).NE.jbtyp) THEN
         nod = jmpb(nod)
         IF(nod.NE.0) GOTO 10
      ENDIF
 
      lstjpb = nod
 
C  EXITS
C  -----
 
      RETURN
900   WRITE(bort_str,'("BUFRLIB: LSTJPB - TABLE NODE (",I7,") IS OUT '//
     . 'OF BOUNDS, < LOWER BOUNDS (",I7,"); TAG IS ",A10)')
     . node,inode(lun),tag(node)
      CALL bort(bort_str)
901   WRITE(bort_str,'("BUFRLIB: LSTJPB - TABLE NODE (",I7,") IS OUT '//
     . 'OF BOUNDS, > UPPER BOUNDS (",I7,"); TAG IS ",A10)')
     . node,isc(inode(lun)),tag(node)
      CALL bort(bort_str)
      END