maxout.f

Go to the documentation of this file.

C> @file
C> @brief Define a customized maximum length for output BUFR messages.
C>
C> @authors J. Woollen, J. Ator @date 2002-05-14
 
C> This subroutine allows the user to define the maximum length of a
C> BUFR message that can be written to an output file by the BUFRLIB
C> software.
C>
C> This subroutine can be called from within an application program at
C> any time after the initial call to subroutine openbf(), and the
C> specified value MAXO will then be used for all future BUFR messages
C> written by the software to all output files for the remainder of
C> the program, unless another call is made to this same subroutine
C> to reset the value of MAXO again.  Otherwise, if this subroutine
C> is never called, a default maximum message length is used for all
C> output files, as set via an initial internal call to subroutine
C> bfrini().
C>
C> @param[in] MAXO --  integer: New maximum length (in bytes) for
C>                     all BUFR messages written to all output files
C>                     - 0 = Set MAXO to the maximum value allowed
C>                           by the BUFRLIB software
C>
C> @authors J. Woollen, J. Ator @date 2002-05-14
      RECURSIVE SUBROUTINE maxout(MAXO)
 
      USE modv_mxmsgl
      USE modv_im8b
 
      USE moda_bitbuf
 
      COMMON /maxcmp/ maxcmb,maxrow,maxcol,ncmsgs,ncsubs,ncbyts
      COMMON /dxtab / maxdx,idxv,nxstr(10),ldxa(10),ldxb(10),ldxd(10),
     .                ld30(10),dxstr(10)
      COMMON /quiet / iprt
 
      CHARACTER*128   errstr
      CHARACTER*56    dxstr
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
C     CHECK FOR I8 INTEGERS
 
      IF(im8b) THEN
         im8b=.false.
 
         CALL x84(maxo,my_maxo,1)
         CALL maxout(my_maxo)
 
         im8b=.true.
         RETURN
      ENDIF
 
      IF((maxo.EQ.0).OR.(maxo.GT.mxmsgl)) THEN
         newsiz = mxmsgl
      ELSE
         newsiz = maxo
      ENDIF
 
      IF(iprt.GE.0) THEN
         IF(maxbyt.NE.newsiz) THEN
      CALL errwrt('++++++++++++++BUFR ARCHIVE LIBRARY+++++++++++++++++')
      WRITE ( unit=errstr, fmt='(A,A,I7,A,I7)' )
     . 'BUFRLIB: MAXOUT - THE RECORD LENGTH OF ALL BUFR MESSAGES ',
     . 'CREATED FROM THIS POINT ON IS BEING CHANGED FROM ', maxbyt,
     . ' TO ', newsiz
      CALL errwrt(errstr)
      CALL errwrt('++++++++++++++BUFR ARCHIVE LIBRARY+++++++++++++++++')
      CALL errwrt(' ')
         ENDIF
      ENDIF
 
      maxbyt = newsiz
      maxcmb = newsiz
      maxdx  = newsiz
 
      RETURN
      END