mtfnam.f

Go to the documentation of this file.

C> @file
C> @brief Determine filenames and check for the existence of
C> corresponding standard and local master table files on the
C> filesystem.
C> @author Ator @date 2017-10-16
 
C> Based on the input arguments, this subroutine determines
c> the names of the corresponding standard and local master table
c> files. It then confirms the existence of these files on the
c> filesystem, using additional information obtained from the most
c> recent call to subroutine mtinfo(), or else as defined within
c> subroutine bfrini() if subroutine mtinfo() was never called.
C>
C> @param[in] IMT - integer: master table number.
C> @param[in] IMTV - integer: master table version number.
C> @param[in] IOGCE - integer: originating center.
C> @param[in] IMTVL - integer: local table version number.
C> @param[in] TBLTYP - character*(*): table type:.
C> - 'TableB' Table B
C> - 'TableD' Table D
C> - 'CodeFlag' Code and Flag Tables
C> @param[out] STDFIL - character*(*): standard master table path/filename.
C> @param[out] LOCFIL - character*(*): local master table path/filename.
C>
C> @author Ator @date 2017-10-16
        SUBROUTINE mtfnam ( IMT, IMTV, IOGCE, IMTVL, TBLTYP,
     .                      STDFIL, LOCFIL )
 
        COMMON /quiet/  iprt
        COMMON /mstinf/ lun1, lun2, lmtd, mtdir
 
        CHARACTER*(*)   STDFIL, LOCFIL, TBLTYP
 
        CHARACTER*16    TBLTYP2
        CHARACTER*20    FMTF
        CHARACTER*100   MTDIR
        CHARACTER*128   BORT_STR
        LOGICAL         FOUND
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
        CALL strsuc ( tbltyp, tbltyp2, ltbt )
 
C*      Determine the standard master table path/filename.
 
        IF ( ( imt .EQ. 0 ) .AND. ( imtv .LE. 13 ) ) THEN
 
C*        For master table 0, version 13 is a superset of all earlier
C*        versions.
 
          stdfil = mtdir(1:lmtd) // '/bufrtab.' // tbltyp2(1:ltbt) //
     .             '_STD_0_13'
        ELSE
          WRITE ( fmtf, '(A,I1,A,I1,A)' )
     .       '(4A,I', isize(imt), ',A,I', isize(imtv), ')'
          WRITE ( stdfil, fmtf ) mtdir(1:lmtd), '/bufrtab.',
     .       tbltyp2(1:ltbt), '_STD_', imt, '_', imtv
        ENDIF
        IF ( iprt .GE. 2 ) THEN
          CALL errwrt('Standard ' // tbltyp2(1:ltbt) // ':')
          CALL errwrt(stdfil)
        ENDIF
        INQUIRE ( file = stdfil, exist = found )
        IF ( .NOT. found ) GOTO 900
 
C*      Now determine the local master table path/filename.
 
C*      Use the local table corresponding to the originating center
C*      and local table version number, if such a table exists.
C*      Otherwise use the local table from NCEP.
 
        WRITE ( fmtf, '(A,I1,A,I1,A,I1,A)' )
     .     '(4A,I', isize(imt), ',A,I', isize(iogce),
     .     ',A,I',  isize(imtvl), ')'
        WRITE ( locfil, fmtf ) mtdir(1:lmtd), '/bufrtab.',
     .       tbltyp2(1:ltbt), '_LOC_', imt, '_', iogce, '_', imtvl
        IF ( iprt .GE. 2 ) THEN
          CALL errwrt('Local ' // tbltyp2(1:ltbt) // ':')
          CALL errwrt(locfil)
        ENDIF
        INQUIRE ( file = locfil, exist = found )
        IF ( .NOT. found ) THEN
 
C*        Use the local table from NCEP.
 
          locfil = mtdir(1:lmtd) // '/bufrtab.' // tbltyp2(1:ltbt) //
     .             '_LOC_0_7_1'
          IF ( iprt .GE. 2 ) THEN
            CALL errwrt('Local ' // tbltyp2(1:ltbt) //
     .                  'not found, so using:')
            CALL errwrt(locfil)
          ENDIF
          INQUIRE ( file = locfil, exist = found )
          IF ( .NOT. found ) GOTO 901
        ENDIF
 
        RETURN
900     bort_str = 'BUFRLIB: MTFNAM - COULD NOT FIND STANDARD FILE:'
        CALL bort2(bort_str,stdfil)
901     bort_str = 'BUFRLIB: MTFNAM - COULD NOT FIND LOCAL FILE:'
        CALL bort2(bort_str,locfil)
        END