nemtbax.f

Go to the documentation of this file.

C> @file
C> @brief Search for a Table A descriptor within the internal DX
C> BUFR tables
C>
C> @author J. Woollen @date 1999-11-18
 
C> This subroutine searches for a descriptor within Table A of the
C> internal DX BUFR tables.
C>
C> It is similar to subroutine nemtba(), except it returns an INOD
C> value of 0 if the descriptor is not found in Table A, whereas
C> nemtba() will call subroutine bort() in such cases.
C>
C> @param[in] LUN - integer: Internal I/O stream index associated
C>                   with DX BUFR tables
C> @param[in] NEMO - character*(*): Mnemonic for Table A descriptor
C> @param[out] MTYP - integer: Message type corresponding to NEMO
C> @param[out] MSBT - integer: Message subtype corresponding to NEMO
C> @param[out] INOD - integer:
C>                     - Positional index of NEMO within internal
C>                       Table A, if found
C>                     - 0, otherwise
C>
C> @author J. Woollen @date 1999-11-18
      SUBROUTINE nemtbax(LUN,NEMO,MTYP,MSBT,INOD)
 
      USE moda_tababd
 
      CHARACTER*(*) NEMO
      CHARACTER*128 BORT_STR
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
      inod = 0
 
C  LOOK FOR NEMO IN TABLE A
C  ------------------------
 
      DO i=1,ntba(lun)
      IF(taba(i,lun)(4:11).EQ.nemo) THEN
         mtyp = idna(i,lun,1)
         msbt = idna(i,lun,2)
         inod = mtab(i,lun)
         IF(mtyp.LT.0 .OR. mtyp.GT.255) GOTO 900
         IF(msbt.LT.0 .OR. msbt.GT.255) GOTO 901
         GOTO 100
      ENDIF
      ENDDO
 
C  EXITS
C  -----
 
100   RETURN
900   WRITE(bort_str,'("BUFRLIB: NEMTBAX - INVALID MESSAGE TYPE (",I4'//
     . ',") RETURNED FOR MENMONIC ",A)') mtyp,nemo
      CALL bort(bort_str)
901   WRITE(bort_str,'("BUFRLIB: NEMTBAX - INVALID MESSAGE SUBTYPE ("'//
     . ',I4,") RETURNED FOR MENMONIC ",A)') msbt,nemo
      CALL bort(bort_str)
      END