numtab.f

Go to the documentation of this file.

C> @file
C> @brief Get information about a descriptor, based on the WMO
C> bit-wise representation of an FXY value.
C>
C> @author J. Woollen @date 1994-01-06
 
C> Get information about a descriptor, based on the WMO
C> bit-wise representation of an FXY value.
C>
C> This subroutine returns information about a descriptor from the
C> internal DX BUFR tables, based on the bit-wise representation of
C> the FXY value associated with that descriptor.
C>
C> For an description of the WMO bit-wise representation of the FXY
C> value, see ifxy().
C>
C> @param[in] LUN - integer: Internal I/O stream index associated
C> with DX BUFR tables.
C> @param[in] IDN - integer: WMO bit-wise representation of FXY value
C> for descriptor.
C> @param[out] NEMO - character*(*): Mnemonic associated with IDN.
C> @param[out] TAB - character: Type associated with IDN:
C> - 'B' Table B descriptor
C> - 'D' Table D descriptor
C> - 'C' Table C operator
C> - 'R' Replication descriptor
C> - 'F' Replication factor
C> @param[out] IRET - integer:
C> - Positional index of IDN within internal Table B, if TAB = 'B'.
C> - Positional index of IDN within internal Table D, if TAB = 'D'.
C> - The X portion of the FXY value in IDN, if TAB = 'C'.
C> - ((-1) * the Y portion of the FXY value in IDN), if TAB = 'R' and the
C>   replication is regular (i.e. non-delayed).
C> - 5 if TAB = 'R' or TAB = 'F' and the replication is 1-bit delayed.
C> - 4 if TAB = 'R' or TAB = 'F' and the replication is 8-bit delayed (stack).
C> - 3 if TAB = 'R' or TAB = 'F' and the replication is 8-bit delayed.
C> - 2 if TAB = 'R' or TAB = 'F' and the replication is 16-bit delayed.
C> - 0 otherwise
C>
C> @author J. Woollen @date 1994-01-06
      SUBROUTINE numtab(LUN,IDN,NEMO,TAB,IRET)
 
C     Note that the values within the COMMON /REPTAB/ arrays were
C     initialized within subroutine BFRINI.
 
      COMMON /reptab/ idnr(5,2),typs(5,2),reps(5,2),lens(5)
 
      CHARACTER*(*) NEMO
      CHARACTER*6   ADN30,CID
      CHARACTER*3   TYPS
      CHARACTER*1   REPS,TAB
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
      nemo = ' '
      iret = 0
      tab = ' '
 
C  LOOK FOR A REPLICATOR OR A REPLICATION FACTOR DESCRIPTOR
C  --------------------------------------------------------
 
      IF(idn.GE.idnr(1,1) .AND. idn.LE.idnr(1,2)) THEN
 
C        Note that the above test is checking whether IDN is the bit-
C        wise representation of a FXY (descriptor) value denoting F=1
C        regular (i.e. non-delayed) replication, since, as was
C        initialized within subroutine BFRINI,
C        IDNR(1,1) = IFXY('101000'), and IDNR(1,2) = IFXY('101255').
 
         tab  = 'R'
         iret = -mod(idn,256)
         GOTO 100
      ENDIF
 
      DO i=2,5
         IF(idn.EQ.idnr(i,1)) THEN
            tab  = 'R'
            iret = i
            GOTO 100
         ELSEIF(idn.EQ.idnr(i,2)) THEN
            tab  = 'F'
            iret = i
            GOTO 100
         ENDIF
      ENDDO
 
C  LOOK FOR IDN IN TABLE B AND TABLE D
C  -----------------------------------
 
      CALL numtbd(lun,idn,nemo,tab,iret)
      IF(iret.NE.0) GOTO 100
 
C  LOOK FOR IDN IN TABLE C
C  -----------------------
 
      cid = adn30(idn,6)
      IF (iokoper(cid).EQ.1) THEN
         nemo = cid(1:6)
         READ(nemo,'(1X,I2)') iret
         tab  = 'C'
         GOTO 100
      ENDIF
 
C  EXIT
C  ----
 
100   RETURN
      END