nvnwin.f

Go to the documentation of this file.

C> @file
C> @brief Search for all occurrences of a specified node within a
C> specified portion of the current data subset.
C>
C> @author Woollen @date 1994-01-06
 
C> This function looks for and returns all occurrences of a
C> specified node within the portion of the current subset buffer
C> bounded by the indices inv1 and inv2. The resulting list is a
C> stack of "event" indices for the requested node.
C>
C> @param[in] NODE - integer: jump/link table index to look for.
C> @param[in] LUN - integer: i/o stream index into internal memory arrays.
C> @param[in] INV1 - integer: starting index of the portion of the subset buffer in which to look.
C> @param[in] INV2 - integer: ending index of the portion of the subset buffer in which to look.
C> @param[out] INVN - integer: array of stack "event" indices for node.
C> @param[in] NMAX - integer: dimensioned size of invn; used by the function to ensure
C> that it does not overflow the invn array.
C>
C> @return number of indices within invn.
C>
C> @author Woollen @date 1994-01-06
      FUNCTION nvnwin(NODE,LUN,INV1,INV2,INVN,NMAX)
 
      USE moda_usrint
 
      COMMON /quiet / iprt
 
      CHARACTER*128 bort_str
      dimension     invn(nmax)
 
C----------------------------------------------------------------------
C----------------------------------------------------------------------
 
      nvnwin = 0
 
      IF(node.EQ.0) THEN
         IF(iprt.GE.1) THEN
      CALL errwrt('+++++++++++++++++++++WARNING+++++++++++++++++++++++')
      CALL errwrt('BUFRLIB: NVNWIN - NODE=0, IMMEDIATE RETURN')
      CALL errwrt('+++++++++++++++++++++WARNING+++++++++++++++++++++++')
      CALL errwrt(' ')
         ENDIF
         GOTO 100
      ENDIF
 
      DO i=1,nmax
         invn(i) = 1e9
      ENDDO
 
C  SEARCH BETWEEN INV1 AND INV2
C  ----------------------------
 
      DO n=inv1,inv2
         IF(inv(n,lun).EQ.node) THEN
            IF(nvnwin+1.GT.nmax) GOTO 900
            nvnwin = nvnwin+1
            invn(nvnwin) = n
         ENDIF
      ENDDO
 
C  EXITS
C  -----
 
100   RETURN
900   WRITE(bort_str,'("BUFRLIB: NVNWIN - THE NUMBER OF EVENTS, '//
     . 'NVNWIN (",I5,") EXCEEDS THE LIMIT, NMAX (",I5,")")') nvnwin,nmax
      CALL bort(bort_str)
      END