parstr.f

Go to the documentation of this file.

C> @file
C> @brief Parse a string containing one or more substrings into an array of substrings.
C> @author J. Ator @date 2007-01-19
 
C> Parse a string containing one or more substrings into an array of substrings.
C>
C> This subroutine parses a string containing one or more
C> substrings into an array of substrings. The separator for the
C> substrings is specified during input, and multiple adjacent
C> occurrences of this character will be treated as a single
C> occurrence when the string is actually parsed.
C>
C> @param[in] STR - character*(*): string.
C> @param[out] TAGS - character*(*): array of substrings
C> @param[in] MTAG - integer: dimensioned size of TAGS within calling program;
C> used by the subroutine to make sure it doesn't overflow the TAGS array.
C> @param[out] NTAG - integer: number of substrings returned in TAGS
C> @param[in] SEP - character*1: separator character for substrings.
C> @param[in] LIMIT80 - logical: .true. if an abort should occur when STR is
C> longer than 80 characters; included for historical consistency with old subroutine parseq.
C>
C> @author J. Ator @date 2007-01-19
      SUBROUTINE parstr(STR,TAGS,MTAG,NTAG,SEP,LIMIT80)
 
      CHARACTER*(*) STR,TAGS(MTAG)
      CHARACTER*128 BORT_STR1,BORT_STR2
      CHARACTER*1   SEP
      LOGICAL       SUBSTR,LIMIT80
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
      lstr = len(str)
      ltag = len(tags(1))
      IF( limit80 .AND. (lstr.GT.80) ) GOTO 900
      ntag = 0
      nchr = 0
      substr = .false.
 
      DO i=1,lstr
 
      IF( .NOT.substr .AND. (str(i:i).NE.sep) ) THEN
         ntag = ntag+1
         IF(ntag.GT.mtag) GOTO 901
         tags(ntag) = ' '
      ENDIF
 
      IF( substr .AND. (str(i:i).EQ.sep) ) nchr = 0
      substr = str(i:i).NE.sep
 
      IF(substr) THEN
         nchr = nchr+1
         IF(nchr.GT.ltag) GOTO 902
         tags(ntag)(nchr:nchr) = str(i:i)
      ENDIF
 
      ENDDO
 
C  EXITS
C  -----
 
      RETURN
900   WRITE(bort_str1,'("BUFRLIB: PARSTR - INPUT STRING (",A,") HAS ")')
     . str
      WRITE(bort_str2,'(18X,"LENGTH (",I4,"), > LIMIT OF 80 CHAR.")')
     . lstr
      CALL bort2(bort_str1,bort_str2)
901   WRITE(bort_str1,'("BUFRLIB: PARSTR - INPUT STRING (",A,") '//
     . 'CONTAINS",I4)') str,ntag
      WRITE(bort_str2,'(18X,"SUBSTRINGS, EXCEEDING THE LIMIT {",I4,'//
     . '" - THIRD (INPUT) ARGUMENT}")') mtag
      CALL bort2(bort_str1,bort_str2)
902   WRITE(bort_str1,'("BUFRLIB: PARSTR - INPUT STRING (",A,") ")') str
      WRITE(bort_str2,'(18X,"CONTAINS A PARSED SUBSTRING WITH LENGTH '//
     . 'EXCEEDING THE MAXIMUM OF",I4," CHARACTERS")') ltag
      CALL bort2(bort_str1,bort_str2)
      END