ufbcpy.f

Go to the documentation of this file.

C> @file
C> @brief Copy a BUFR data subset.
C>
C> @author J. Woollen @date 1994-01-06
 
C> Copy a BUFR data subset.
C>
C> This subroutine copies a BUFR data subset from one Fortran logical
C> unit to another.
C>
C> It is similar to subroutine copysb(), except that here a
C> BUFR data subset should have already been read into internal arrays
C> for logical unit LUBIN via a previous call to one of the
C> [subset-reading subroutines](@ref hierarchy), whereas copysb()
C> only requires that a BUFR message should have already been read
C> into internal arrays via a previous call to one of the
C> [message-reading subroutines](@ref hierarchy).
C>
C> For logical unit LUBOT, a BUFR message should already be open
C> for output within internal arrays via a previous call to one of
C> the [message-writing subroutines](@ref hierarchy).
C>
C> The [DX BUFR Table information](@ref dfbftab) associated with
C> each of the logical units LUBIN and LUBOT must contain identical
C> definitions for the data subset to be copied.
C>
C> @param[in] LUBIN - integer: Fortran logical unit number for
C> source BUFR file.
C> @param[in] LUBOT - integer: Fortran logical unit number for
C> target BUFR file.
C>
C> @author J. Woollen @date 1994-01-06
      RECURSIVE SUBROUTINE ufbcpy(LUBIN,LUBOT)
 
      USE modv_im8b
 
      USE moda_usrint
      USE moda_msgcwd
      USE moda_ufbcpl
      USE moda_tables
 
C----------------------------------------------------------------------
C----------------------------------------------------------------------
 
C  CHECK FOR I8 INTEGERS
C  ---------------------
 
      IF(im8b) THEN
         im8b=.false.
 
         CALL x84(lubin,my_lubin,1)
         CALL x84(lubot,my_lubot,1)
         CALL ufbcpy(my_lubin,my_lubot)
 
         im8b=.true.
         RETURN
      ENDIF
 
C  CHECK THE FILE STATUSES AND I-NODE
C  ----------------------------------
 
      CALL status(lubin,lui,il,im)
      IF(il.EQ.0) GOTO 900
      IF(il.GT.0) GOTO 901
      IF(im.EQ.0) GOTO 902
      IF(inode(lui).NE.inv(1,lui)) GOTO 903
 
      CALL status(lubot,luo,il,im)
      IF(il.EQ.0) GOTO 904
      IF(il.LT.0) GOTO 905
      IF(im.EQ.0) GOTO 906
 
      IF(inode(lui).NE.inode(luo)) THEN
        IF( (tag(inode(lui)).NE.tag(inode(luo))) .OR.
     .     (iok2cpy(lui,luo).NE.1) ) GOTO 907
      ENDIF
 
C  EVERYTHING OKAY COPY USER ARRAY FROM LUI TO LUO
C  -----------------------------------------------
 
      nval(luo) = nval(lui)
 
      DO n=1,nval(lui)
      inv(n,luo) = inv(n,lui)
      nrfelm(n,luo) = nrfelm(n,lui)
      val(n,luo) = val(n,lui)
      ENDDO
 
      luncpy(luo)=lubin
 
C  EXITS
C  -----
 
      RETURN
900   CALL bort('BUFRLIB: UFBCPY - INPUT BUFR FILE IS CLOSED, IT MUST'//
     . ' BE OPEN FOR INPUT')
901   CALL bort('BUFRLIB: UFBCPY - INPUT BUFR FILE IS OPEN FOR '//
     . 'OUTPUT, IT MUST BE OPEN FOR INPUT')
902   CALL bort('BUFRLIB: UFBCPY - A MESSAGE MUST BE OPEN IN INPUT '//
     . 'BUFR FILE, NONE ARE')
903   CALL bort('BUFRLIB: UFBCPY - LOCATION OF INTERNAL TABLE FOR '//
     . 'INPUT BUFR FILE DOES NOT AGREE WITH EXPECTED LOCATION IN '//
     . 'INTERNAL SUBSET ARRAY')
904   CALL bort('BUFRLIB: UFBCPY - OUTPUT BUFR FILE IS CLOSED, IT '//
     . 'MUST BE OPEN FOR OUTPUT')
905   CALL bort('BUFRLIB: UFBCPY - OUTPUT BUFR FILE IS OPEN FOR '//
     . 'INPUT, IT MUST BE OPEN FOR OUTPUT')
906   CALL bort('BUFRLIB: UFBCPY - A MESSAGE MUST BE OPEN IN OUTPUT '//
     . 'BUFR FILE, NONE ARE')
907   CALL bort('BUFRLIB: UFBCPY - INPUT AND OUTPUT BUFR FILES MUST '//
     . 'HAVE THE SAME INTERNAL TABLES, THEY ARE DIFFERENT HERE')
      END