ufbcup.f

Go to the documentation of this file.

C> @file
C> @brief Copy unique elements of a data subset.
C>
C> @author Woollen @date 1994-01-06
 
C> Copy unique elements of a data subset.
C>
C> This subroutine makes one copy of each unique element in an input
C> subset buffer into the identical mnemonic slot in the output subset
C> buffer.
C>
C> Before this subroutine is called:
C> - The input file must be opened for input with openbf().
C> - a message must be read, as with readmg().
C> - a subset of data loaded into memory, as with readsb().
C> - the output file must be opened for output with openbf().
C> - a message must be created in the output file, as with openmg().
C>
C> After this subroutine is called, writsb() must be called on the output
C> file to write the subset to file.
C>
C> @param[in] LUBIN - integer: fortran logical unit number for input BUFR
C> file.
C> @param[in] LUBOT - integer: fortran logical unit number for output
C> BUFR file.
C>
C> @author Woollen @date 1994-01-06
      RECURSIVE SUBROUTINE ufbcup(LUBIN,LUBOT)
 
      USE modv_im8b
 
      USE moda_usrint
      USE moda_msgcwd
      USE moda_tables
      USE moda_ivttmp
 
      CHARACTER*10 tago
 
C----------------------------------------------------------------------
C----------------------------------------------------------------------
 
C  CHECK FOR I8 INTEGERS
C  ---------------------
 
      IF(im8b) THEN
         im8b=.false.
 
         CALL x84(lubin,my_lubin,1)
         CALL x84(lubot,my_lubot,1)
         CALL ufbcup(my_lubin,my_lubot)
 
         im8b=.true.
         RETURN
      ENDIF
 
C  CHECK THE FILE STATUSES AND I-NODE
C  ----------------------------------
 
      CALL status(lubin,lui,il,im)
      IF(il.EQ.0) GOTO 900
      IF(il.GT.0) GOTO 901
      IF(im.EQ.0) GOTO 902
      IF(inode(lui).NE.inv(1,lui)) GOTO 903
 
      CALL status(lubot,luo,il,im)
      IF(il.EQ.0) GOTO 904
      IF(il.LT.0) GOTO 905
      IF(im.EQ.0) GOTO 906
 
C  MAKE A LIST OF UNIQUE TAGS IN INPUT BUFFER
C  ------------------------------------------
 
      ntag = 0
 
      DO 5 ni=1,nval(lui)
      nin = inv(ni,lui)
      IF(itp(nin).GE.2) THEN
         DO nv=1,ntag
         IF(ttmp(nv).EQ.tag(nin)) GOTO 5
         ENDDO
         ntag = ntag+1
         itmp(ntag) = ni
         ttmp(ntag) = tag(nin)
      ENDIF
5     ENDDO
 
      IF(ntag.EQ.0) GOTO 907
 
C  GIVEN A LIST MAKE ONE COPY OF COMMON ELEMENTS TO OUTPUT BUFFER
C  --------------------------------------------------------------
 
      DO 10 nv=1,ntag
      ni = itmp(nv)
      DO no=1,nval(luo)
      tago = tag(inv(no,luo))
      IF(ttmp(nv).EQ.tago) THEN
         val(no,luo) = val(ni,lui)
         GOTO 10
      ENDIF
      ENDDO
10    ENDDO
 
C  EXITS
C  -----
 
      RETURN
900   CALL bort('BUFRLIB: UFBCUP - INPUT BUFR FILE IS CLOSED, IT '//
     . 'MUST BE OPEN FOR INPUT')
901   CALL bort('BUFRLIB: UFBCUP - INPUT BUFR FILE IS OPEN FOR '//
     . 'OUTPUT, IT MUST BE OPEN FOR INPUT')
902   CALL bort('BUFRLIB: UFBCUP - A MESSAGE MUST BE OPEN IN INPUT '//
     . 'BUFR FILE, NONE ARE')
903   CALL bort('BUFRLIB: UFBCUP - LOCATION OF INTERNAL TABLE FOR '//
     . 'INPUT BUFR FILE DOES NOT AGREE WITH EXPECTED LOCATION IN '//
     . 'INTERNAL SUBSET ARRAY')
904   CALL bort('BUFRLIB: UFBCUP - OUTPUT BUFR FILE IS CLOSED, IT '//
     . 'MUST BE OPEN FOR OUTPUT')
905   CALL bort('BUFRLIB: UFBCUP - OUTPUT BUFR FILE IS OPEN FOR '//
     . 'INPUT, IT MUST BE OPEN FOR OUTPUT')
906   CALL bort('BUFRLIB: UFBCUP - A MESSAGE MUST BE OPEN IN OUTPUT '//
     . 'BUFR FILE, NONE ARE')
907   CALL bort('BUFRLIB: UFBCUP - THERE ARE NO ELEMENTS (TAGS) IN '//
     . 'INPUT SUBSET BUFFER')
      END