x48.F

Go to the documentation of this file.

C> @file
C> @brief Encode one or more 4-byte integer values as 8-byte integer values.
C>
C> @author J. Woollen @date 2022-10-12
 
C> Encode one or more 4-byte integer values as 8-byte integer values.
C>
C> @note IIN4 and IOUT8 may be the same array, as long as the underlying
C> memory contains sufficient space for the equivalent number of 8-byte
C> integer values.
C>
C> @param[in] IIN4 - integer(*): Value(s) encoded as 4-byte integers
C> @param[out] IOUT8 - integer(*): Value(s) from IIN4 now re-encoded as 8-byte integers
C> @param[in] NVAL - integer: Number of values in IIN4 to be re-encoded
C>
C> @author J. Woollen @date 2022-10-12
 
        SUBROUTINE x48(IIN4,IOUT8,NVAL)
 
        INTEGER   IIN4(*),IOUT8(*)
 
        INTEGER   ONES /-1/
        INTEGER   ZERO / 0/
 
C       Call subroutine WRDLEN, in case it hasn't already been called.
 
        CALL wrdlen
 
C       IHI points to the first byte of the high-order (i.e. most
C       significant) 4-byte integer word within an 8-byte integer word.
C       ILO points to the first byte of the low-order (i.e. least
C       significant) 4-byte integer word within an 8-byte integer word.
 
#ifdef BIG_ENDIAN
        ihi=1
        ilo=5
#else
        ihi=5
        ilo=1
#endif
 
C       Re-encode the 4-byte values as 8-byte values.
 
        DO k = nval,1,-1
          l=2*k-1
          CALL mvb(iin4(k),1,itmp,ilo,4)
          iout8(l)=itmp
          IF(iout8(l)<0) THEN
             CALL mvb(ones,1,iout8(l),ihi,4)
          ELSE
             CALL mvb(zero,1,iout8(l),ihi,4)
          ENDIF
        END DO
 
        RETURN
        END