w3swldmd Module Reference

Source term module for swell dissipation. More...

Functions/Subroutines
subroutine, public	w3swl4 (A, CG, WN, DAIR, S, D)
	FIXME. More...
subroutine, public	w3swl6 (A, CG, WN, S, D)
	Turbulent dissipation of narrow-banded swell. More...

Detailed Description

Source term module for swell dissipation.

Source term for swell dissipation based on different physics that can be independently selected from the input and whitecapping dissipation terms in the model setup.

Author

H. L. Tolman

Date

21-Nov-2011

Function/Subroutine Documentation

w3swl4()

subroutine, public w3swldmd::w3swl4	(	real, dimension(nspec), intent(in)	A,
		real, dimension(nk), intent(in)	CG,
		real, dimension(nk), intent(in)	WN,
		real, intent(in)	DAIR,
		real, dimension(nspec), intent(out)	S,
		real, dimension(nspec), intent(out)	D
	)

FIXME.

A, S, D all stored as 1-D arrays with dimension NTH*NK (column by column).

Parameters

[in]	A	Action density spectrum.
[in]	CG	Group velocities.
[in]	WN	Wavenumbers.
[in]	DAIR	Air density.
[out]	S	Source term.
[out]	D	Diagonal term of the derivative.

Author

H. L. Tolman

Date

13-Aug-2021

Definition at line 94 of file w3swldmd.F90.

    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           H. L. Tolman            |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         13-Aug-2021 |
    !/                  +-----------------------------------+
    !/
    !/    29-May-2009 : Origination (w3srcxmd.ftn)          ( version 3.14 )
    !/    06-Jan-2012 : Implementation                         (S. Zieger)
    !/    13-Aug-2021 : Consider DAIR a variable           ( version x.xx )
    !/
    !  1. Purpose :
    !
    !     FIXME
    !
    !  2. Method :
    !
    !  3. Parameters :
    !
    !      Parameter list
    !     ----------------------------------------------------------------
    !      A¹      R.A. I  Action density spectrum
    !      CG      R.A. I  Group velocities
    !      WN      R.A. I  Wavenumbers
    !      DAIR    R.A. I   Air density
    !      S¹      R.A. O  Source term
    !      D¹      R.A. O  Diagonal term of derivative
    !      ¹ Stored as 1-D array with dimension NTH*NK (column by column).
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      IRANGE    Func. W3SWLDMD
    !      STRACE    Subr. W3SERVMD Subroutine tracing.
    !     ----------------------------------------------------------------
    !
    !  5. Called by :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      W3SRCE    Subr. W3SRCEMD Source term integration.
    !      W3EXPO    Subr.   N/A    Point output post-processor.
    !      GXEXPO    Subr.   N/A    GrADS point output post-processor.
    !     ----------------------------------------------------------------
    !
    !  6. Error messages :
    !
    !       None.
    !
    !  7. Remarks :
    !
    !  8. Structure :
    !
    !     See comments in source code.
    !
    !  9. Switches :
    !
    !     !/S  Enable subroutine tracing.
    !
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    USE constants, ONLY: grav, dwat
    USE w3gdatmd,  ONLY: nk, nth, nspec, sig2, dden, fte, swl6b1
#ifdef W3_S
    USE w3servmd, ONLY: strace
#endif
    !/
    IMPLICIT NONE
    !/
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    REAL, INTENT(IN)  :: A(NSPEC), CG(NK), WN(NK), DAIR
    REAL, INTENT(OUT) :: S(NSPEC), D(NSPEC)
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
#ifdef W3_S
    INTEGER, SAVE     :: IENT = 0
#endif
    INTEGER           :: IKN(NK), ITH
    REAL, PARAMETER   :: VA = 1.4e-5 ! Air kinematic viscosity (used in WAM).
    REAL              :: EB(NK), WN2(NSPEC), EMEAN
    REAL              :: FE, AORB, RE, RECRIT, UOSIG, CDSV
    !/
    !/ ------------------------------------------------------------------- /
    !/
#ifdef W3_S
    CALL strace (ient, 'W3SWL4')
#endif
    !
    ikn = irange(1,nspec,nth)
    d   = 0.
    wn2 = 0.
    !
    DO ith = 1, nth
      wn2(ikn+(ith-1)) = wn        ! Wavenumbers to all directions.
    END DO
    !
    eb     = sum(reshape(a,(/ nth,nk /)),1) * dden(1:nk) / cg
    emean  = sum(eb) + (eb(nk) / dden(nk)) * fte
    !
    aorb   = 2.0*sqrt(emean)
    !
    eb     = sum(reshape(a*sig2**2,(/ nth,nk /)),1) * dden(1:nk) / cg
    uosig  = 2.0*sqrt(sum(eb))
 
    fe     = swl6b1    ! (from NAMELIST)
    !     FE     = 0.001     ! (from NAMELIST)
    !/             0.001 - 0.019 with median value 0.007 (Ardhuin et al 2009, Babanin 2011)
    cdsv   = 1.2
    !
    recrit = 1.0e5
    re     = 4.0 * uosig * aorb / va
    !
    IF (re .GT. recrit) THEN
      d = -(16.0/grav) * (dair/dwat) * fe * (sig2**2) *uosig
    ELSE
      d = -2.0 * (dair/dwat) * cdsv * wn2 * sqrt(2.0 * va * sig2)
    END IF
    !
    s = d * a
    !
    !  WRITE(*,*) ' FE       =',FE
    !  WRITE(*,*) ' HS       =',4.*SQRT(EMEAN)
    !  WRITE(*,*) ' UOSIG    =',UOSIG
    !  WRITE(*,*) ' AORB     =',AORB
    !  WRITE(*,*) ' RE/RECRIT=',RE/RECRIT
    !  WRITE(*,*) ' SWL4_tot =',SUM(SUM(RESHAPE(S,(/ NTH,NK /)),1)*DDEN/CG)
    !/
    !/ End of W3SWL4 ----------------------------------------------------- /
    !/

References w3gdatmd::dden, constants::dwat, w3gdatmd::fte, constants::grav, w3gdatmd::nk, w3gdatmd::nspec, w3gdatmd::nth, w3gdatmd::sig2, w3servmd::strace(), and w3gdatmd::swl6b1.

w3swl6()

subroutine, public w3swldmd::w3swl6	(	real, dimension(nspec), intent(in)	A,
		real, dimension(nk), intent(in)	CG,
		real, dimension(nk), intent(in)	WN,
		real, dimension(nspec), intent(out)	S,
		real, dimension(nspec), intent(out)	D
	)

Turbulent dissipation of narrow-banded swell.

A, S, D all stored as 1-D arrays with dimension NTH*NK (column by column).

Described in Babanin (2011, Section 7.5). Babanin 2011: Cambridge Press, 295-321, 463pp.

S = D * A

Parameters

[in]	A	Action density spectrum.
[in]	CG	Group velocities.
[in]	WN	Wavenumbers.
[out]	S	Source term.
[out]	D	Diagonal term of the derivative.

Author

H. L. Tolman

Date

16-Feb-2012

Definition at line 252 of file w3swldmd.F90.

    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           H. L. Tolman            |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         16-Feb-2012 |
    !/                  +-----------------------------------+
    !/
    !/    29-May-2009 : Origination (w3srcxmd.ftn)          ( version 3.14 )
    !/    16-Feb-2012 : Implementation                      ( version 4.07 )
    !/                                                         (S. Zieger)
    !/
    !  1. Purpose :
    !
    !     Turbulent dissipation of narrow-banded swell as described in
    !     Babanin (2011, Section 7.5).
    !
    !     Babanin 2011: Cambridge Press, 295-321, 463pp.
    !
    !  2. Method :
    !
    !     S = D * A
    !
    !  3. Parameters :
    !
    !      Parameter list
    !     ----------------------------------------------------------------
    !      A¹      R.A. I  Action density spectrum
    !      CG      R.A. I  Group velocities
    !      WN      R.A. I  Wavenumbers
    !      S¹      R.A. O  Source term
    !      D¹      R.A. O  Diagonal term of derivative
    !      ¹ Stored as 1-D array with dimension NTH*NK (column by column).
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      IRANGE    Func. W3SWLDMD
    !      STRACE    Subr. W3SERVMD Subroutine tracing.
    !     ----------------------------------------------------------------
    !
    !  5. Called by :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      W3SRCE    Subr. W3SRCEMD Source term integration.
    !      W3EXPO    Subr.   N/A    Point output post-processor.
    !      GXEXPO    Subr.   N/A    GrADS point output post-processor.
    !     ----------------------------------------------------------------
    !
    !  6. Error messages :
    !
    !       None.
    !
    !  7. Remarks :
    !
    !  8. Structure :
    !
    !     See comments in source code.
    !
    !  9. Switches :
    !
    !     !/S  Enable subroutine tracing.
    !
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    USE constants, ONLY: grav
    USE w3gdatmd,  ONLY: nk, nth, nspec, sig, dden, dth
    USE w3gdatmd,  ONLY: swl6cstb1, swl6b1, fte, ftwn
#ifdef W3_T6
    USE w3odatmd,  ONLY: ndst
#endif
#ifdef W3_S
    USE w3servmd, ONLY: strace
#endif
    !/
    IMPLICIT NONE
    !/
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    REAL, INTENT(IN)    :: A(NSPEC), CG(NK), WN(NK)
    REAL, INTENT(OUT)   :: S(NSPEC), D(NSPEC)
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
#ifdef W3_S
    INTEGER, SAVE     :: IENT = 0
#endif
    INTEGER             :: IK, ITH, IKN(NK)
    REAL, DIMENSION(NK) :: ABAND, KMAX, ANAR, BN, AORB, DDIS
    REAL                :: K(NTH,NK), B1
    !/
    !/ ------------------------------------------------------------------- /
    !/
#ifdef W3_S
    CALL strace (ient, 'W3SWL6')
#endif
    !
    !/ 0) --- Initialize parameters -------------------------------------- /
    ikn   = irange(1,nspec,nth)            ! Index vector for array access, e.g.
    !                                            ! in form of WN(1:NK) == WN2(IKN).
    aband = sum(reshape(a,(/ nth,nk /)),1) ! action density as function of wavenumber
    ddis  = 0.
    d     = 0.
    b1    = swl6b1                         ! empirical constant from NAMELIST
    !
    !/ 1) --- Choose calculation of steepness a*k ------------------------ /
    !/        Replace the measure of steepness with the spectral
    !         saturation after Banner et al. (2002) ---------------------- /
    k     = reshape(a,(/ nth,nk /))
    kmax  = maxval(k,1)
    DO ik = 1,nk
      IF (kmax(ik).LT.1.0e-34) THEN
        k(1:nth,ik) = 1.
      ELSE
        k(1:nth,ik) = k(1:nth,ik)/kmax(ik)
      END IF
    END DO
    anar  = 1.0/( sum(k,1) * dth )
    bn    = anar * ( aband * sig(1:nk) * dth ) * wn**3
    !
    IF (.NOT.swl6cstb1) THEN
      !
      !/    --- A constant value for B1 attenuates swell too strong in the
      !/        western central Pacific (i.e. cross swell less than 1.0m).
      !/        Workaround is to scale B1 with steepness a*kp, where kp is
      !/        the peak wavenumber. SWL6B1 remains a scaling constant, but
      !/        with different magnitude.  --------------------------------- /
      ik    = maxloc(aband,1)         ! Index for peak
      !         EMEAN = SUM(ABAND * DDEN / CG)  ! Total sea surface variance
      b1    = swl6b1 * ( 2. * sqrt(sum(aband*dden/cg)) * wn(ik) )
      !
    END IF
    !
    !/ 2) --- Calculate the derivative term only (in units of 1/s) ------- /
    DO ik = 1,nk
      IF (aband(ik) .GT. 1.e-30) THEN
        ddis(ik) = -(2./3.) * b1 * sig(ik) * sqrt(bn(ik))
      END IF
    END DO
    !
    !/ 3) --- Apply dissipation term of derivative to all directions ----- /
    DO ith = 1, nth
      d(ikn+(ith-1)) = ddis
    END DO
    !
    s = d * a
    !
    !  WRITE(*,*) ' B1       =',B1
    !  WRITE(*,*) ' DDIS_tot =',SUM(DDIS*ABAND*DDEN/CG)
    !  WRITE(*,*) ' EDENS_tot=',sum(aband*dden/cg)
    !  WRITE(*,*) ' EDENS_tot=',sum(aband*sig*dth*dsii/cg)
    !  WRITE(*,*) ' '
    !  WRITE(*,*) ' SWL6_tot =',sum(SUM(RESHAPE(S,(/ NTH,NK /)),1)*DDEN/CG)
    !
    !/
    !/ End of W3SWL6 ----------------------------------------------------- /
    !/

References w3gdatmd::dden, w3gdatmd::dth, w3gdatmd::fte, w3gdatmd::ftwn, constants::grav, w3odatmd::ndst, w3gdatmd::nk, w3gdatmd::nspec, w3gdatmd::nth, w3gdatmd::sig, w3servmd::strace(), w3gdatmd::swl6b1, and w3gdatmd::swl6cstb1.

Referenced by gxexpo(), w3exnc(), w3expo(), and w3srcemd::w3srce().