gets1loc.f

Go to the documentation of this file.

C> @file
C> @brief Get the location of a specified value within Section 1
C> of a BUFR message
C>
C> @author J. Ator @date 2005-11-29
 
C> This subroutine returns the location of a specified value within
C> Section 1 of a BUFR message.
C>
C> The location and availability of any particular value within
C> Section 1 of a BUFR message can vary depending on the edition
C> number used to encode the message.  This subroutine will work
C> for BUFR edition 2, 3, or 4.
C>
C> @param[in]  S1MNEM  -- character*(*): Value whose location within
C>                        Section 1 is to be determined:
C>                         - 'LEN1'  = Length (in bytes) of Section 1
C>                         - 'BMT'   = BUFR master table
C>                         - 'OGCE'  = Originating center
C>                         - 'GSES'  = Originating subcenter
C>                         - 'USN'   = Update sequence number
C>                         - 'ISC2'  = Flag indicating absence/presence of
C>                                     (optional) Section 2 in BUFR message:
C>                                    - 0 = Section 2 absent
C>                                    - 1 = Section 2 present
C>                         - 'MTYP'  = Data category
C>                         - 'MSBTI' = Data subcategory (international)
C>                         - 'MSBT'  = Data subcategory (local)
C>                         - 'MTV'   = Version number of master table
C>                         - 'MTVL'  = Version number of local tables
C>                         - 'YCEN'  = Year of century (1-100)
C>                         - 'CENT'  = Century (e.g., 20 for years 1901-2000,
C>                                     21 for years 2001-2100)
C>                         - 'YEAR'  = Year (4-digit)
C>                         - 'MNTH'  = Month
C>                         - 'DAYS'  = Day
C>                         - 'HOUR'  = Hour
C>                         - 'MINU'  = Minute
C>                         - 'SECO'  = Second
C> @param[in]  IBEN    -- integer: BUFR edition number
C> @param[out] ISBYT   -- integer: Number of starting byte within Section 1
C>                        which contains value corresponding to S1MNEM
C> @param[out] IWID    -- integer: Width (in bits) of value corresponding
C>                        to S1MNEM, counting from the first bit of the
C>                        byte pointed to by ISBYT
C> @param[out] IRET    -- integer: Return code:
C>                        - 0 = normal return
C>                        - -1 = S1MNEM is invalid for BUFR edition IBEN
C>
C> @remarks
C> - S1MNEM = 'GSES' is only valid for IBEN = 3 or 4.
C> - S1MNEM = 'YCEN' or 'CENT' is only valid for IBEN = 2 or 3.
C> - S1MNEM = 'YEAR', 'SECO', or 'MSBTI' is only valid for IBEN = 4.
C>
C> @author J. Ator @date 2005-11-29
        RECURSIVE SUBROUTINE gets1loc(S1MNEM,IBEN,ISBYT,IWID,IRET)
 
        USE modv_im8b
 
        CHARACTER*(*) s1mnem
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
C       Check for I8 integers.
 
        IF(im8b) THEN
           im8b=.false.
 
           CALL x84(iben,my_iben,1)
           CALL gets1loc(s1mnem,my_iben,isbyt,iwid,iret)
           CALL x48(isbyt,isbyt,1)
           CALL x48(iwid,iwid,1)
           CALL x48(iret,iret,1)
 
           im8b=.true.
           RETURN
        ENDIF
 
        iret = 0
        iwid = 8
 
        IF(s1mnem.EQ.'LEN1') THEN
            isbyt = 1
            iwid = 24
        ELSE IF(s1mnem.EQ.'BMT') THEN
            isbyt = 4
        ELSE IF(s1mnem.EQ.'OGCE') THEN
            IF(iben.EQ.3) THEN
                isbyt = 6
            ELSE
 
C               Note that this location is actually the same for both
C               Edition 2 *and* Edition 4 of BUFR!
 
                isbyt = 5
                iwid = 16
            ENDIF
        ELSE IF(s1mnem.EQ.'GSES') THEN
            IF(iben.EQ.3) THEN
                isbyt = 5
            ELSE IF(iben.EQ.4) THEN
                isbyt = 7
                iwid = 16
            ELSE
                iret = -1
            ENDIF
        ELSE IF(s1mnem.EQ.'USN') THEN
            IF(iben.EQ.4) THEN
                isbyt = 9
            ELSE
                isbyt = 7
            ENDIF
        ELSE IF(s1mnem.EQ.'ISC2') THEN
            iwid = 1
            IF(iben.EQ.4) THEN
                isbyt = 10
            ELSE
                isbyt = 8
            ENDIF
        ELSE IF(s1mnem.EQ.'MTYP') THEN
            IF(iben.EQ.4) THEN
                isbyt = 11
            ELSE
                isbyt = 9
            ENDIF
        ELSE IF(s1mnem.EQ.'MSBTI') THEN
            IF(iben.EQ.4) THEN
                isbyt = 12
            ELSE
                iret = -1
            ENDIF
        ELSE IF(s1mnem.EQ.'MSBT') THEN
            IF(iben.EQ.4) THEN
                isbyt = 13
            ELSE
                isbyt = 10
            ENDIF
        ELSE IF(s1mnem.EQ.'MTV') THEN
            IF(iben.EQ.4) THEN
                isbyt = 14
            ELSE
                isbyt = 11
            ENDIF
        ELSE IF(s1mnem.EQ.'MTVL') THEN
            IF(iben.EQ.4) THEN
                isbyt = 15
            ELSE
                isbyt = 12
            ENDIF
        ELSE IF(s1mnem.EQ.'YEAR') THEN
            IF(iben.EQ.4) THEN
                isbyt = 16
                iwid = 16
            ELSE
                iret = -1
            ENDIF
        ELSE IF(s1mnem.EQ.'YCEN') THEN
            IF(iben.LT.4) THEN
                isbyt = 13
            ELSE
                iret = -1
            ENDIF
        ELSE IF(s1mnem.EQ.'CENT') THEN
            IF(iben.LT.4) THEN
                isbyt = 18
            ELSE
                iret = -1
            ENDIF
        ELSE IF(s1mnem.EQ.'MNTH') THEN
            IF(iben.EQ.4) THEN
                isbyt = 18
            ELSE
                isbyt = 14
            ENDIF
        ELSE IF(s1mnem.EQ.'DAYS') THEN
            IF(iben.EQ.4) THEN
                isbyt = 19
            ELSE
                isbyt = 15
            ENDIF
        ELSE IF(s1mnem.EQ.'HOUR') THEN
            IF(iben.EQ.4) THEN
                isbyt = 20
            ELSE
                isbyt = 16
            ENDIF
        ELSE IF(s1mnem.EQ.'MINU') THEN
            IF(iben.EQ.4) THEN
                isbyt = 21
            ELSE
                isbyt = 17
            ENDIF
        ELSE IF(s1mnem.EQ.'SECO') THEN
            IF(iben.EQ.4) THEN
                isbyt = 22
            ELSE
                iret = -1
            ENDIF
        ELSE
            iret = -1
        ENDIF
 
        RETURN
        END