pktdd.f

Go to the documentation of this file.

C> @file
C> @brief Store information about a child mnemonic within the internal arrays.
C>
C> @author Woollen @date 1994-01-06
 
C> Store information about a child mnemonic within the internal arrays.
C>
C> This subroutine stores information about a "child"
C> mnemonic within the internal BUFR table D entry (in module @ref moda_tababd)
C> for a table D sequence ("parent") mnemonic when the
C> "child" mnemonic is contained within the sequence represented by
C> the "parent" mnemonic (as determined within seqsdx()).
C>
C> @param[in] ID - integer: positional index of parent mnemonic within internal BUFR table D array tabd(*,*).
C> @param[in] LUN - integer: File ID.
C> @param[in] IDN - integer: WMO bit-wise representation of FXY value corresponding to child mnemonic.
C> - 0 = delete all information about all child mnemonics from within tabd(id,lun).
C> @param[out] IRET - integer: total number of child mnemonics stored thus far
C> (including idn) for the parent mnemonic given by tabd(id,lun).
C> - 0 information was cleared from tabd(id,lun) because input IDN value was 0
C> - -1 bad counter value or maximum number of child mnemonics already stored
C> for this parent mnemonic
C>
C> @author Woollen @date 1994-01-06
      SUBROUTINE pktdd(ID,LUN,IDN,IRET)
 
      USE modv_maxcd
      USE moda_tababd
 
      COMMON /dxtab / maxdx,idxv,nxstr(10),ldxa(10),ldxb(10),ldxd(10),
     .                ld30(10),dxstr(10)
      COMMON /quiet / iprt
 
      CHARACTER*128 ERRSTR
      CHARACTER*56  DXSTR
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
      ldd = ldxd(idxv+1)+1
 
C     LDD points to the byte within TABD(ID,LUN) which contains (in
C     packed integer format) a count of the number of child mnemonics
C     stored thus far for this parent mnemonic.
 
C  ZERO THE COUNTER IF IDN IS ZERO
C  -------------------------------
 
      IF(idn.EQ.0) THEN
         CALL ipkm(tabd(id,lun)(ldd:ldd),1,0)
         iret = 0
         GOTO 100
      ENDIF
 
C  UPDATE THE STORED DESCRIPTOR COUNT FOR THIS TABLE D ENTRY
C  ---------------------------------------------------------
 
      nd = iupm(tabd(id,lun)(ldd:ldd),8)
 
C     ND is the (unpacked) count of the number of child mnemonics
C     stored thus far for this parent mnemonic.
 
      IF(nd.LT.0 .OR. nd.EQ.maxcd) THEN
      IF(iprt.GE.0) THEN
      CALL errwrt('+++++++++++++++++++++WARNING+++++++++++++++++++++++')
         IF(nd.LT.0) THEN
            WRITE ( unit=errstr, fmt='(A,I4,A)' )
     .        'BUFRLIB: PKTDD - BAD COUNTER VALUE (=', nd,
     .        ') - RETURN WITH IRET = -1'
         ELSE
            WRITE ( unit=errstr, fmt='(A,I4,A,A)' )
     .        'BUFRLIB: PKTDD - MAXIMUM NUMBER OF CHILD MNEMONICS (=',
     .        maxcd, ') ALREADY STORED FOR THIS PARENT - RETURN WITH ',
     .        'IRET = -1'
         ENDIF
      CALL errwrt(errstr)
      CALL errwrt('+++++++++++++++++++++WARNING+++++++++++++++++++++++')
      CALL errwrt(' ')
      ENDIF
         iret = -1
         GOTO 100
      ELSE
         nd = nd+1
         CALL ipkm(tabd(id,lun)(ldd:ldd),1,nd)
         iret = nd
      ENDIF
 
C  PACK AND STORE THE DESCRIPTOR
C  -----------------------------
 
      idm = ldd+1 + (nd-1)*2
 
C     IDM points to the starting byte within TABD(ID,LUN) at which
C     the IDN value for this child mnemonic will be stored (as a
C     packed integer of width = 2 bytes).
 
      CALL ipkm(tabd(id,lun)(idm:idm),2,idn)
 
C  EXIT
C  ----
 
100   RETURN
      END