uptdd.f

Go to the documentation of this file.

C> @file
C> @brief Get the WMO bit-wise representation of the FXY value
C> corresponding to a child mnemonic in a Table D sequence.
C>
C> @author J. Woollen @date 1994-01-06
 
C> Returns the WMO bit-wise representation of the FXY value corresponding
C> to a child mnemonic of a Table D sequence parent mnemonic.
C>
C> For a description of the WMO bit-wise representation of the FXY
C> value, see ifxy().
C>
C> @param[in] ID - integer: Positional index of parent mnemonic
C> within internal BUFR Table D array tabd.
C> @param[in] LUN - integer: File ID.
C> @param[in] IENT - integer: Ordinal indicator of child mnemonic to
C> return from within tabd(id,lun) sequence. 0 indicates that a count
C> of the total number of child mnemonics within the sequence will be
C> returned.
C> @param[out] IRET - integer: Return value:
C> - WMO bit-wise representation of FXY value corresponding to IENT'th
C>   child mnemonic, if input IENT was > 0.
C> - Total number of child mnemonics, if input IENT was 0.
C>
C> @author J. Woollen @date 1994-01-06
 
      SUBROUTINE uptdd(ID,LUN,IENT,IRET)
 
      USE moda_tababd
 
      COMMON /dxtab / maxdx,idxv,nxstr(10),ldxa(10),ldxb(10),ldxd(10),
     .                ld30(10),dxstr(10)
 
      CHARACTER*128 BORT_STR
      CHARACTER*56  DXSTR
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
      ldd = ldxd(idxv+1)+1
 
C  CHECK IF IENT IS IN BOUNDS
C  --------------------------
 
      ndsc = iupm(tabd(id,lun)(ldd:ldd),8)
 
      IF(ient.EQ.0) THEN
         iret = ndsc
         GOTO 100
      ELSEIF(ient.LT.0 .OR. ient.GT.ndsc) THEN
         GOTO 900
      ENDIF
 
C  RETURN THE DESCRIPTOR INDICATED BY IENT
C  ---------------------------------------
 
      idsc = ldd+1 + (ient-1)*2
      iret = iupm(tabd(id,lun)(idsc:idsc),16)
 
C  EXITS
C  -----
 
100   RETURN
900   WRITE(bort_str,'("BUFRLIB: UPTDD - VALUE OF THIRD ARGUMENT IENT'//
     . ' (INPUT) IS OUT OF RANGE (IENT =",I4,")")') ient
      CALL bort(bort_str)
      END