getbit.f

Go to the documentation of this file.

C> @file
C> @brief Compute number of bits and round field.
C> @author Mark Iredell @date 1992-10-31
 
C> The number of bits required to pack a given field.
C> The field is rounded off to the decimal scaling for packing.
C> The minimum and maximum rounded field values are also returned.
C> For particular binary and decimal scalings is computed.
C> Grib bitmap masking for valid data is optionally used.
C>
C> Program history log:
C> - Mark Iredell 1996-09-16
C>
C> @param[in] IBM Integer bitmap flag (=0 for no bitmap).
C> @param[in] IBS Integer binary scaling (e.g. ibs=3 to round field
C> to nearest eighth value).
C> @param[in] IDS Integer decimal scaling (e.g. ids=3 to round field
C> to nearest milli-value) (note that ids and ibs can both be nonzero,
C> e.g. ids=1 and ibs=1 rounds to the nearest twentieth).
C> @param[in] LEN Integer length of the field and bitmap.
C> @param[in] MG Integer (LEN) bitmap if ibm=1 (0 to skip, 1 to keep).
C> @param[in] G Real (LEN) field.
C> @param[out] GROUND Real (LEN) field rounded to decimal and binary scaling
C> (set to zero where bitmap is 0 if ibm=1).
C> @param[out] GMIN Real minimum valid rounded field value.
C> @param[out] GMAX Real maximum valid rounded field value.
C> @param[out] NBIT Integer number of bits to pack.
C>
C> @note CRAY FORTRAN
C>
C> @author Mark Iredell @date 1992-10-31
      SUBROUTINE getbit(IBM,IBS,IDS,LEN,MG,G,GROUND,GMIN,GMAX,NBIT)
      dimension mg(len),g(len),ground(len)
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  ROUND FIELD AND DETERMINE EXTREMES WHERE BITMAP IS ON
      s=2.**ibs*10.**ids
      IF(ibm.EQ.0) THEN
        ground(1)=nint(g(1)*s)/s
        gmax=ground(1)
        gmin=ground(1)
        DO i=2,len
          ground(i)=nint(g(i)*s)/s
          gmax=max(gmax,ground(i))
          gmin=min(gmin,ground(i))
        ENDDO
      ELSE
        i1=1
        dowhile(i1.LE.len.AND.mg(i1).EQ.0)
          i1=i1+1
        ENDDO
        IF(i1.LE.len) THEN
          DO i=1,i1-1
            ground(i)=0.
          ENDDO
          ground(i1)=nint(g(i1)*s)/s
          gmax=ground(i1)
          gmin=ground(i1)
          DO i=i1+1,len
            IF(mg(i).NE.0) THEN
              ground(i)=nint(g(i)*s)/s
              gmax=max(gmax,ground(i))
              gmin=min(gmin,ground(i))
            ELSE
              ground(i)=0.
            ENDIF
          ENDDO
        ELSE
          DO i=1,len
            ground(i)=0.
          ENDDO
          gmax=0.
          gmin=0.
        ENDIF
      ENDIF
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  COMPUTE NUMBER OF BITS
      nbit=log((gmax-gmin)*s+0.9)/log(2.)+1.
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      RETURN
      END